您是否曾尝试过像下图所示那样，将项目从一个列表框移动到另一个列表框？接下来，我将为您介绍如何在 Excel 中实现这一操作。

在列表框之间移动项目

在列表框之间移动项目

Excel 本身并未提供内置功能来完成此任务，但我有一段 VBA 代码可助您轻松实现。

1. 首先，您需要在名为 Admin_Lists 的新工作表中创建一份数据列表，该列表将作为列表框中的选项显示。

2. 然后选中这些数据，在名称框中将其命名为 ItemList。参见截图：

3. 然后在包含两个列表框的工作表中，单击开发工具> 插入> 列表框（Active X 控件），并绘制两个列表框。参见截图：

如果您的开发工具选项卡在功能区中被隐藏，如何在 Excel 2007/2010/2013 功能区中显示开发工具选项卡？ 本文将为您详细介绍如何快速显示它！

太棒了！在 Excel 中像使用 Chrome、Edge、Firefox 和 Safari 一样高效地使用 Tabs！
每天为您节省 50% 的时间，并减少成千上万次鼠标点击！

4. 然后单击开发工具> 插入> 命令按钮（Active X 控件），并在两个列表框之间绘制四个按钮。参见截图：

现在，请使用新建的名称为这四个命令按钮重命名。

5. 选中第一个命令按钮，单击属性，在属性窗格中，为其指定名称 BTN_moveAllRight，并在>>旁边的文本框中输入 Caption。参见截图：

6. 重复步骤 5，按以下名称重命名其余三个命令按钮，并在标题中分别填入不同的箭头符号。参见截图：

BTN_MoveSelectedRight

BTN_moveAllLeft

BTN_MoveSelectedLeft

7. 右键单击包含列表框和命令按钮的工作表标签，从上下文菜单中选择查看代码。参见截图：

8. 将下方的宏代码复制并粘贴到 Microsoft Visual Basic for Applications 窗口中的模块脚本里，保存后关闭窗口。参见截图

VBA：在两个列表框之间移动项目

Private Sub Worksheet_Activate()
'UpdatebyExtendoffice20171117
    Dim xCell As Range
    Dim xRg As Range
    Set xRg = Sheets("Admin_Lists").Range("ItemList")
    Me.ListBox1.Clear
    Me.ListBox2.Clear
    With Me.ListBox1
        .LinkedCell = ""
        .ListFillRange = ""
        For Each xCell In xRg
            If xCell <> "" Then
                .AddItem xCell.Value
            End If
        Next xCell
    End With
    Me.ListBox1.MultiSelect = fmMultiSelectMulti
    Me.ListBox2.MultiSelect = fmMultiSelectMulti
End Sub

Private Sub BTN_MoveSelectedLeft_Click()
    Call moveSigle(Me.ListBox2, Me.ListBox1)
End Sub

Private Sub BTN_MoveSelectedRight_Click()
    Call moveSigle(Me.ListBox1, Me.ListBox2)
End Sub

Private Sub BTN_moveAllLeft_Click()
    Call moveAll(Me.ListBox2, Me.ListBox1)
End Sub

Private Sub BTN_moveAllRight_Click()
    Call moveAll(Me.ListBox1, Me.ListBox2)
End Sub

Sub moveAll(xListBox1 As Object, xListBox2 As Object)
    Dim I As Long
    For I = 0 To xListBox1.ListCount - 1
        xListBox2.AddItem xListBox1.List(I)
    Next I
    xListBox1.Clear
End Sub

Sub moveSigle(xListBox1 As Object, xListBox2 As Object)
    Dim I As Long
    For I = 0 To xListBox1.ListCount - 1
        If I = xListBox1.ListCount Then Exit Sub
        If xListBox1.Selected(I) = True Then
            xListBox2.AddItem xListBox1.List(I)
            xListBox1.RemoveItem I
            I = I - 1
        End If
    Next
End Sub

9. 随后切换至其他工作表，再返回包含列表框的工作表，您将发现列表数据已显示在第一个列表框中。单击命令按钮，即可在两个列表框之间轻松移动项目。

移动所选项

移动全部